[原创] 突破策略的各种方式

期货市场的价格以趋势方式演变,如果我们能想办法抓住趋势,就能赚到这部分趋势行情的钱。那么,用什么方式来抓住趋势呢?比较简单的一种方法就是用突破策略。构建价格的上下轨,或者支撑位、压力位。当价格超过上轨,我们认为行情即将启动,开仓做多,反之亦然。


突破策略原理
从结果上讲,大趋势上涨或下跌必然会突破其间的关键价格位置,
突破从原因上讲,市场涨跌取决于买卖双方实力对比。当价位冲破上一时段的最高点时,在上一时段任何价位做空头的人都无一例外被套牢,它当中肯定有一部分要认赔平仓出局,反过来又给升势推波助澜。相反,当行情跌破上一时段的最低价时,在上一时段任何一点做多头的统统都出现浮动亏损,其中一定有部分要止损作平仓卖出,正好对跌势落井下石。所以对突破的研究,是必须和必要的课题。
现在我们就以螺纹指数15分钟K线为数据源进行回测,处于研究目的滑点和手续费暂不考虑,看看突破策略的各种方式.



1.波动率(布林带)突破策略
 

MID:MA(CLOSE,35);//收盘价的35日简单移动平均
TMP2:=STD(CLOSE,35);// 收盘价的35日估算标准差
TOP:MID+2*TMP2;//布林上轨
BOTTOM:MID-2*TMP2;//布林下轨
CROSS(C,TOP),BK; //收盘价上穿布林上轨  买开仓
CROSSDOWN(C,BOTTOM),SK;// 收盘价下穿布林下轨  卖开仓
CROSSDOWN(C,MID),SP; //收盘价下穿布林中轨  卖平仓
CROSS(C,MID),BP; //收盘价上穿布林中轨  买平仓
AUTOFILTER;


布林带十分常见,波动率代表了最近价格的变化范围,如果某周期的变化超过了一定倍数的标准差,我们将此视为偶然事件,代表了趋势的启动。回测结果如下:


2.一定周期内的最高价最低价突破策略
 

HH:HV(H,20);//取前20根K线最高价最大值
LL:LV(L,20);//取前20根K线最低价最小值
H>HH,BPK;//最高价大于HH
L<LL,SPK;//最低价小于LL
AUTOFILTER;


如果行情出现明显趋势,显然会在某时刻超过最近一段时间的最高价或低于最低价,依据此原理,可以写出简单的突破策略。回测结果如下:


3.开盘价固定上下轨突破策略
 

R1:=BARSLAST(DAY-REF(DAY,1)<>0);//当前K线到当天第一根K线之间周期数
R5:REF(O,R1)+7;//当天开盘价+7赋值给R5
R6:R5+22;//R5+13赋值给R6
R7:R5-22;//R5-13赋值给R7
CROSS(H,R6),BK;//最高价上穿R6,买开
CROSS(R7,L),SK;//最低价下穿R7,卖开
CROSS(R5,L),SP;//最低价下穿R5,多单平仓
CROSS(H,R5),BP;//最高价上穿R5,空单平仓
AUTOFILTER;


从前面的策略可以看出,突破策略需要找到突破的上下轨,那么直接简单固定上下轨价格是否可行呢?本策略即以开盘价为依据,加减一定的价格作为突破的参考,可谓简单粗暴回测的表现也不错。


4.观察开盘一段时间确定突破上下轨
 

N:=BARSLAST(DATE<>REF(DATE,1))+1;//当日第几根K线
HH:VALUEWHEN(TIME<=0930,HHV(H,N));//9:30时的当日最高价
LL:VALUEWHEN(TIME<=0930,LLV(L,N));//9:30时的当日最低价
C>HH&&TIME>0930&&TIME<1450,BK;//价格大于HH并且时间大于9:30并且时间小于1450,买开仓
C<LL&&TIME>0930&&TIME<1450,SK;//价格小于LL并且时间大于9:30并且时间小于1450,买开仓
TIME>=1450,CLOSEOUT;//14:50时清仓
AUTOFILTER;


本策略在开盘后观察半小时,以此时间段内的最高最低价作为突破的上下轨策略,并且日内收盘前清仓,原理和策略3一脉相承。表现如下:


5.波动范围突破

A:=REF(HIGH,1)-REF(LOW,1);          
B:=REF(HIGH,2)-REF(LOW,2);          
C:=REF(HIGH,3)-REF(LOW,3);
D:=A*0.2+B*0.3+C*0.5;
J:=5/100;
K:=13/100;
(CLOSE-OPEN)>D*J,BK;
(OPEN-CLOSE)>D*K,SP;
(OPEN-CLOSE)>D*K,SK;
(CLOSE-OPEN)>D*J,BP;
AUTOFILTER;


和布林带突破策略相似,主要参考最高价-最低价变化的平均,当变化范围过大时,代表了突破。回测结果如下:


6.最高最低价均线构建突破策略
 

MA30:=MA(CLOSE,30);
SG:=(MA(HIGH,30));//上轨
XG:=(MA(LOW,30));//下轨
D:=MA30>=REF(MA30,1) && REF(MA30,1)>=REF(MA30,2);//多
K:=MA30<=REF(MA30,1) && REF(MA30,1)<=REF(MA30,2);//空
D && CLOSE>SG,BK(1);
CROSS(XG,CLOSE),SP(1);
K && XG>CLOSE,SK(1);
CROSS(CLOSE,SG),BP(1);


本策略的上下轨为最高最低价均线,加上逐步加减仓。回测结果如下:

总之,突破策略的形式多种多样,主要在于如何构建上下轨道,宽客在线平台上传了很多突破类型的策略和文章,搜索“突破”即可找到
,相信看了这么多,读者也应该有了自己的思路,不妨自己尝试一下。

免责声明:信息仅供参考,不构成投资及交易建议。投资者据此操作,风险自担。

如果觉得文章对你有用,请随意赞赏收藏
相关推荐
相关下载
登录后评论
最新评论 (1)
Copyright © 2019 宽客在线